I have a simple function which is then defined as a list and invoked as a list:

f:{x*x}
q)(f; neg)[1; 2]
-2
q)(f; neg)[1; 3]
-3
q)(f; neg)[2; 3]
3
q)(f; neg)[4; 3]
3

for the (f; neg)[1; 3] - it returns the most right as neg (-3), but then it no longer returns neg as the first argument becomes > 1, e.g: (f; neg)[2; 3] -> returns 3

I have a simple function which is then defined as a list and invoked as a list:

f:{x*x}
q)(f; neg)[1; 2]
-2
q)(f; neg)[1; 3]
-3
q)(f; neg)[2; 3]
3
q)(f; neg)[4; 3]
3

for the (f; neg)[1; 3] - it returns the most right as neg (-3), but then it no longer returns neg as the first argument becomes > 1, e.g: (f; neg)[2; 3] -> returns 3

• kdb+

2 Answers 2

The first argument is being used to index into the list of functions, and the second argument is applied to the result:

//case 1
(f; neg)[1; 2]

//find the 1st item in the list (which is -: aka neg)
q)((f;neg)[1])
-:

//apply the second input (2) to neg to get -2
q)((f;neg)[1])@2
-2

//case 2
(f; neg)[2; 2]

//find the second item in the list (it doesnt exist, returns identity function [see Alexander's answer])
q)(f;neg)[2]

//apply 2 to identity (just returns 2)
q)((f;neg)[2])@2
2

This behaviour is expected. What you are doing is you're indexing into the list of functions and then applying the function that has been returned to the parameter you pass as second parameter. You can see this here

q)f
{x*x}
q)(f;neg)[0]
{x*x}
q)(f;neg)[1]
-:
q)neg
-:

Basically what happens is, the first parameter from [1;3] is the index into your list of functions and the second parameter 3 is the value you are applying. Now, why does it not work for the last two examples.
Whenever you index into a list with an index that's out of bound, it returns the corresponding null element of the datatype for that list.

q)(1 2 3) 6
0N
q)(0101b) 6
0b

The null element of a list of functions is the identity function (::) which simply returns the parameter passed to it as it is

q)(neg;min;max;avg)5
q)(neg;min;max;avg;::)4
q)(neg;min;max;avg;::)[4;5]
5
q)(::)5
5

Hope this helps. You can read more about the identity function here https://code.kx/q/ref/identity/
And indexing here https://code.kx/q4m3/3_Lists/#34-indexing